Gradleタスク

JProfilerは、専用のタスクを使用してGradleからのプロファイリングをサポートしています。さらに、JProfilerには対応するGradleタスクを持つスナップショット操作用のコマンドライン実行ファイルが多数用意されています。

Gradleタスクの使用

GradleビルドファイルでJProfiler Gradleタスクを使用できるようにするには、pluginsブロックを使用できます。

plugins {
    id 'com.jprofiler' version 'X.Y.Z'
}

この目的でGradleプラグインリポジトリを使用しない場合は、Gradleプラグインがファイルbin/gradle.jarで配布されています。

デフォルトでは、プラグインはプラグインと同じバージョンのJProfilerディストリビューションを自動プロビジョニングし、<Gradle user home>/jprofiler/distの下に保存します。キャッシュディレクトリをオーバーライドするには、jprofilerブロックでautoProvisioningCacheDirプロパティを設定します。

代わりにローカルのJProfilerインストール環境を使用したい場合は、JProfilerがインストールされている場所をJProfiler Gradleプラグインに指定します。macOSの場合、インストールディレクトリはアプリケーションバンドルのパス（例: /Applications/JProfiler.app）になります。

jprofiler {
    installDir = file('/path/to/jprofiler/home')
}

Gradleからのプロファイリング

com.jprofiler.gradle.JavaProfile型のタスクを使用すると、任意のJavaプロセスをプロファイルできます。このクラスはGradleの組み込みJavaExecを拡張しているため、プロセスの構成に同じ引数を使用できます。テストのプロファイリングには、GradleのTestタスクを拡張したcom.jprofiler.gradle.TestProfile型のタスクを使用します。

追加の設定を行わない場合、両方のタスクはインタラクティブなプロファイリングセッションを開始し、プロファイリングエージェントはデフォルトポート8849でJProfiler GUIからの接続を待機します。オフラインプロファイリングの場合は、エクスポートされた設定ファイルを参照するか、以下の表に示す属性を使用して一般的なセッション設定および自動記録を直接構成できます。

プロジェクトによってコンパイルされたmainメソッドを持つJavaクラスをプロファイルする例を以下に示します:

task run(type: com.jprofiler.gradle.JavaProfile) {
    mainClass = 'com.mycorp.MyMainClass'
    classpath sourceSets.main.runtimeClasspath
    offline = true
    callTreeMode = 'sampling'
    profile = ['com.mycorp.', 'org.example.']
    snapshotFile = file('build/snapshots/run.jps')
    recording = ['cpu', 'allocation', 'jdbc']
    duration = '10m'
}

設定ファイル不要（config-less）の属性ではカバーされていない高度な設定を行うには、設定ファイルをエクスポートし、configFileとsessionIdでそれを参照します。

task run(type: com.jprofiler.gradle.JavaProfile) {
    mainClass = 'com.mycorp.MyMainClass'
    classpath sourceSets.main.runtimeClasspath
    offline = true
    sessionId = 80
    configFile = file('path/to/jprofiler_config.xml')
}

このタスクの実行可能な例は、api/samples/offlineサンプルプロジェクトで確認できます。標準のJavaExecタスクとは異なり、JavaProfileタスクはcreateProcess()を呼び出すことでバックグラウンドで開始することもできます。この機能のデモについては、api/samples/mbeanサンプルプロジェクトを参照してください。

プロファイリングに必要なVMパラメータが必要な場合、com.jprofiler.gradle.SetAgentpathPropertyタスクは、propertyName属性で構成された名前のプロパティにそのパラメータを割り当てます。JProfilerプラグインを適用すると、setAgentPathPropertyという名前のこのタイプのタスクがプロジェクトに自動的に追加されます。前の例で使用されるVMパラメータを取得するには、単に以下を

setAgentPathProperty {
    propertyName = 'profilingVmParameter'
    offline = true
    callTreeMode = 'sampling'
    profile = ['com.mycorp.', 'org.example.']
}

プロジェクトに追加して、他のタスクにsetAgentPathPropertyへの依存関係を追加するだけです。そうすれば、そのタスクの実行フェーズでプロジェクトプロパティprofilingVmParameterを使用できます。プロパティを他のタスクのプロパティに割り当てる場合は、Gradleの設定フェーズではなく実行フェーズであることを確実にするために、その使用箇所をdoFirst {...}コードブロックで囲んでください。

スナップショットからのデータのエクスポート

com.jprofiler.gradle.Exportタスクを使用すると、保存されたスナップショットからビューをエクスポートでき、 bin/jpexportコマンドラインツールの引数を再現します。以下の属性をサポートしています:

エクスポートタスクでは、viewsメソッドを呼び出し、その中でview(name, file[, options])を1回または複数回呼び出すクロージャを渡します。viewの各呼び出しによって1つの出力ファイルが生成されます。name引数はビュー名です。使用可能なビュー名の一覧については、 jpexportコマンドライン実行ファイルのヘルプページを参照してください。引数fileは出力ファイルであり、絶対パスまたはプロジェクトに対する相対パスのファイルです。最後に、オプションのoptions引数は、選択したビューのエクスポートオプションを含むマップです。

エクスポートタスクの使用例は以下のとおりです:

task export(type: com.jprofiler.gradle.Export) {
    snapshotFile = file('snapshot.jps')
    views {
        view('CallTree', 'callTree.html')
        view('HotSpots', 'hotSpots.html',
            [threadStatus: 'all', expandBacktraces: 'true'])
    }
}

スナップショットの比較

bin/jpcompareコマンドラインツールと同様に、com.jprofiler.gradle.Compareタスクは2つ以上のスナップショットを比較できます。属性は以下のとおりです:

エクスポートされるビューがExportタスクに対して定義されるのと同様に、Compareタスクにはcomparisonsメソッドがあり、comparison(name, file[, options])のネストされた呼び出しによって実行すべき比較を定義します。利用可能な比較名の一覧は、 jpcompareコマンドライン実行ファイルのヘルプページで確認できます。

比較タスクの使用例は以下のとおりです:

task compare(type: com.jprofiler.gradle.Compare) {
    snapshotFiles = files('snapshot1.jps', 'snapshot2.jps')
    comparisons {
        comparison('CallTree', 'callTree.html')
        comparison('HotSpots', 'hotSpots.csv',
            [valueSummation: 'total', format: 'csv'])
    }
}

あるいは、複数のスナップショットのテレメトリー比較を作成する場合:

task compare(type: com.jprofiler.gradle.Compare) {
    snapshotFiles = fileTree(dir: 'snapshots', include: '*.jps')
    sortByTime = true
    comparisons {
        comparison('TelemetryHeap', 'heap.html', [valueType: 'maximum'])
        comparison('ProbeTelemetry', 'jdbc.html', [probeId: 'JdbcProbe'])
    }
}

ヒープスナップショットの分析

Gradleタスクcom.jprofiler.gradle.Analyzeは、 bin/jpanalyzeコマンドラインツールと同じ機能を備えています。

このタスクには、処理対象のスナップショットを指定するためのCompareタスクと同様のsnapshotFiles属性と、逆難読化のためのExportタスクと同様のobfuscatorおよびmappingFile属性があります。removeUnreferenced、retainSoft、retainWeak、retainPhantom、retainFinalizer、およびretained属性は、コマンドラインツールの引数に対応しています。

Analyzeタスクの使用例を以下に示します:

task analyze(type: com.jprofiler.gradle.Analyze) {
    snapshotFiles = fileTree(dir: 'snapshots', include: '*.jps')
    retainWeak = true
    obfuscator = 'proguard'
    mappingFile = file('obfuscation.txt')
}